#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

Local $iRadio1, $iRadio2, $iRadio3, $iRadio4, $iRadio5, $msg, $hGUI
$hGUI = GUICreate("Радио кнопка") ; Создаёт окно в центре экрана

GUICtrlCreateGroup("Радио кнопка с переключением", 10, 10, 230, 66) ; элемент Group группирует радиокнопки
$iRadio1 = GUICtrlCreateRadio("Радио кнопка 1", 20, 25, -1, 20)
$iRadio2 = GUICtrlCreateRadio("Радио кнопка 2", 20, 45, -1, 20)
GUICtrlSetState($iRadio2, $GUI_CHECKED)
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUICtrlCreateGroup("Радио кнопка в виде кнопки с иконкой", 10, 95, 230, 80)
$iRadio3 = GUICtrlCreateRadio("-", 30, 120, 40, 40, $BS_PUSHLIKE + $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 22)
GUICtrlSetState(-1, $GUI_CHECKED) ; параметр -1 определяет последнюю использованную переменную

$iRadio4 = GUICtrlCreateRadio("-", 80, 120, 40, 40, $BS_PUSHLIKE + $BS_ICON)
GUICtrlSetImage(-1, "shell32.dll", 23)

$iRadio5 = GUICtrlCreateRadio("-", 130, 120, 40, 40, $BS_PUSHLIKE + $BS_BITMAP)
GUICtrlSetImage(-1, "oemlogo.bmp")
GUICtrlCreateGroup("", -99, -99, 1, 1)

GUISetState() ; показывает созданное окно

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
	$msg = GUIGetMsg()
	Select ; рекомендуется использовать Switch вместо Select
		Case $msg = $GUI_EVENT_CLOSE
			ExitLoop
		Case $msg = $iRadio1 And BitAND(GUICtrlRead($iRadio1), $GUI_CHECKED) = $GUI_CHECKED
			MsgBox(64, 'Информация:', 'В кликнули Радио 1 и этот выбор отмечен визуально.', 0, $hGUI)
		Case $msg = $iRadio2 And BitAND(GUICtrlRead($iRadio2), $GUI_CHECKED) = $GUI_CHECKED
			MsgBox(64, 'Информация:', 'В кликнули Радио 2 и этот выбор отмечен визуально.', 0, $hGUI)
		Case $msg = $iRadio3 And BitAND(GUICtrlRead($iRadio3), $GUI_CHECKED) = $GUI_CHECKED
			MsgBox(64, 'Информация:', 'В кликнули Радио кнопку слева и этот выбор отмечен визуально.', 0, $hGUI)
		Case $msg = $iRadio4 And BitAND(GUICtrlRead($iRadio4), $GUI_CHECKED) = $GUI_CHECKED
			MsgBox(64, 'Информация:', 'В кликнули Радио кнопку в центре и этот выбор отмечен визуально.', 0, $hGUI)
		Case $msg = $iRadio5 And BitAND(GUICtrlRead($iRadio5), $GUI_CHECKED) = $GUI_CHECKED
			MsgBox(64, 'Информация:', 'В кликнули Радио кнопку справа и этот выбор отмечен визуально.', 0, $hGUI)
	EndSelect
WEnd