#include <IE.au3>

; ====================================
; Пример 1 - Открывает пример страницы "basic", вставляет
;				скрипт событий в заголовок (head) страницы, которая создаёт
;				уведомление JavaScript, когда кто-либо кликает на документе
;				После запуска примера кликните на странице, чтобы увидеть сообщение

$oIE = _IE_Example("basic")
_IEHeadInsertEventScript($oIE, "document", "onclick", "alert('Кто-то кликает на документе!');")

; ====================================
; Пример 2 - Открывает пример страницы "basic", вставляет
;				скрипт событий в заголовок (head) страницы, которая создаёт
;				уведомление JavaScript, когда кто-либо кликает правой кнопкой мыши на
;				документе. И далее событие скрипта возвращает "false", чтобы
;				предотвратить появление контекстного меню правой кнопкой мыши

$oIE = _IE_Example("basic")
_IEHeadInsertEventScript($oIE, "document", "oncontextmenu", "alert('Нет контекстного меню');return false")

; ====================================
; Пример 3 - Открывает пример страницы "basic", вставляет
;				скрипт событий в заголовок (head) страницы, которая создаёт
;				уведомление JavaScript, когда вы собираетесь уйти со страницы
;				и представляет возможность отменить операцию.

$oIE = _IE_Example("basic")
_IEHeadInsertEventScript($oIE, "window", "onbeforeunload", _
		"alert('Пример последующего предупреждения...');return 'В процессе действия изменения могут быть потеряны';")
_IENavigate($oIE, "www.autoitscript.com")

; ====================================
; Пример 4 - Открывает пример страницы "basic", вставляет
;				скрипт событий в заголовок (head) страницы, которая
;				предотвращает выделение текста в документе

$oIE = _IE_Example()
_IEHeadInsertEventScript($oIE, "document", "ondrag", "return false;")
_IEHeadInsertEventScript($oIE, "document", "onselectstart", "return false;")

; ====================================
; Пример 5 - Открывает страницу AutoIt, вставляет
;				скрипт событий в заголовок (head) страницы, которая
;				предотвращает навигацию,при любом клике на ссылке
;				и отправляет кликнутые URL в консоль

$oIE = _IECreate("http://www.autoitscript.com")
$oLinks = _IELinkGetCollection($oIE)
For $oLink In $oLinks
	$sLinkId = _IEPropertyGet($oLink, "uniqueid")
	_IEHeadInsertEventScript($oIE, $sLinkId, "onclick", "return false;")
	ObjEvent($oLink, "_Evt_")
Next

While 1
	Sleep(100)
WEnd

Func _Evt_onClick()
	Local $o_link = @COM_EventObj
	ConsoleWrite($o_link.href & @CRLF)
EndFunc   ;==>_Evt_onClick