#include <IE.au3>

; ====================================
; Пример 1 - Открывает браузер с примером "form", устанавливает значение текста элемента формы

Local $oIE = _IE_Example("form")
Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oText = _IEFormElementGetObjByName($oForm, "textExample")
_IEFormElementSetValue($oText, "Эй! Это работает!")

; ====================================
; Пример 2 - Получает ссылку на указанный элемент формы и устанавливает его значение.
;				в этом примере запрос в поисковой системе Google

$oIE = _IECreate("http://www.google.com")
$oForm = _IEFormGetObjByName($oIE, "f")
Local $oQuery = _IEFormElementGetObjByName($oForm, "q")
_IEFormElementSetValue($oQuery, "AutoIt IE.au3")
_IEFormSubmit($oForm)

; ====================================
; Пример 3 - Устанавливает значение элемента INPUT TYPE=TEXT используя Send()

$oIE = _IE_Example("form")
$oForm = _IEFormGetObjByName($oIE, "ExampleForm")
Local $oInputFile = _IEFormElementGetObjByName($oForm, "textExample")

; Назначает фокус ввода в поле ии далее высылает строку текста
_IEAction($oInputFile, "focus")

; Выделяет текущее содержимое, чтобы перезаписать его.
_IEAction($oInputFile, "selectall")

Send("Это работает!")

; ====================================
; Пример 4 - Устанавливает значение элемента INPUT TYPE=TEXT
;				в невидимое окно, используя ControlSend()

$oIE = _IE_Example("form")

; Скрывает окно браузера, чтобы продемонстрировать высылку текста в невидимое окно
_IEAction($oIE, "invisible")

$oForm = _IEFormGetObjByName($oIE, "ExampleForm")
$oInputFile = _IEFormElementGetObjByName($oForm, "textExample")

; Назначает фокус ввода в поле ии далее высылает строку текста
_IEAction($oInputFile, "focus")

; Выделяет текущее содержимое, чтобы перезаписать его.
_IEAction($oInputFile, "selectall")

; Получает дескриптор окна IE.
Local $hIE = _IEPropertyGet($oIE, "hwnd")
ControlSend($hIE, "", "[CLASS:Internet Explorer_Server; INSTANCE:1]", "Это работает")

MsgBox(4096, "Успешно", "Значение установлено в 'Это работает'")
_IEAction($oIE, "visible")