#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>
#include <Constants.au3>

$Debug_DTP = False ; Проверяет ClassName передаваемый в DTP функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

Global $iMemo

_Main()

Func _Main()
	Local $hDTP

	; Создаёт GUI
	GUICreate("Получает цвет календаря", 400, 300)
	$hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
	$iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
	GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
	GUISetState()

	; Устанавливает формат строки
	_GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

	; Устанавливает цвет элементов календаря
	_GUICtrlDTP_SetMCColor($hDTP, 1, 0xB02B00) ; текст дней
	_GUICtrlDTP_SetMCColor($hDTP, 2, 0x5EFFFE) ; фон заголовка
	_GUICtrlDTP_SetMCColor($hDTP, 3, 0x0000FF) ; текст заголовка
	_GUICtrlDTP_SetMCColor($hDTP, 4, 0x87C4FF) ; фон календаря
	_GUICtrlDTP_SetMCColor($hDTP, 5, 0x997777) ; текст дней не принадлежащих месяцу
	; цвет можно установить с помощью констант $CLR_MONEYGREEN и т.д.

	; Получает цвет DTP
	MemoWrite("Фон между месяцами: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 0), 6))
	MemoWrite("Текст дней .......: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 1), 6))
	MemoWrite("Фон заголовка ....: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 2), 6))
	MemoWrite("Текст заголовка ..: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 3), 6))
	MemoWrite("Фон календаря.....: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 4), 6))
	MemoWrite("Текст прочих дней.: " & "0x" & Hex(_GUICtrlDTP_GetMCColor($hDTP, 5), 6))

	; Цикл выполняется, пока окно не будет закрыто
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	GUIDelete()
EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
	GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite