; Пример 1 - вызов непосредственно MessageBox API
$result = DllCall("user32.dll", "int", "MessageBox", "hwnd", 0, "str", "Некоторый текст", "str", "Такой вот заголовок", "int", 0)



; Пример 2 - вызов функции, которая запрашивает параметры (запустите блокнот)
$hwnd = WinGetHandle("[CLASS:Notepad]")
$result = DllCall("user32.dll", "int", "GetWindowText", "hwnd", $hwnd, "str", "", "int", 32768)
MsgBox(4096, "", _
		$result[0] & @LF & _ ; количество возвращаемых символов
		$result[2]) ; текст заголовка возвращаемый в параметре 2



; Пример 3 - Отображает окно выбора иконок PickIconDlg
$sFileName = @SystemDir & '\shell32.dll'

; Создаёт структуру для хранения индекса иконки
$stIcon = DllStructCreate("int")
$stString = DllStructCreate("wchar[260]")
$structsize = DllStructGetSize($stString) / 2
DllStructSetData($stString, 1, $sFileName)

; Вызывает функцию PickIconDlg из shell32.dll с порядковым номером 62 для этой функции
$aRes = DllCall("shell32.dll", "int", 62, "hwnd", 0, "ptr", DllStructGetPtr($stString), "int", $structsize, "ptr", DllStructGetPtr($stIcon))
If @error Or Not $aRes[0] Then Exit ; Выход в случае нажатия кнопки "Отмена"

$sFileName = DllStructGetData($stString, 1)
$nIconIndex = DllStructGetData($stIcon, 1)

; Отображает выбранные имя файла и номер иконки
MsgBox(4096, "Информация", "Последний выбранный файл: " & $sFileName & @LF & "Индекс иконки: " & $nIconIndex)