#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>

Example()

Func Example()
	Local $hGUI, $hToolTip, $iAdd, $hAdd, $hIcon, $tRect, $Left, $Right, $Top, $Bottom

	$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 350, 200)

	$iAdd = GUICtrlCreateButton("Кнопка с подсказкой", 30, 32, 130, 28)
	$hAdd = GUICtrlGetHandle(-1) ; Получает дескриптор элемента, чтобы использовать для ToolTip

	; Создаёт стиль овальной подсказки
	$hToolTip = _GUIToolTip_Create($hGUI, $TTS_CLOSE + $TTS_BALLOON)

	; Назначает подсказку элементу
	_GUIToolTip_AddTool($hToolTip, 0, "Это текст подсказки", $hAdd, 0, 0, 0, 0, 9 + $TTM_TRACKPOSITION)

	; Получает дескриптор иконки
	$hIcon = _WinAPI_LoadShell32Icon(15)

	; Устанавливает заголовок подсказки
	_GUIToolTip_SetTitle($hToolTip, 'Заголовок', $hIcon)
	GUISetState()

	$tRect = _WinAPI_GetWindowRect($hAdd)
	$Left = DllStructGetData($tRect, "Left")
	$Right = DllStructGetData($tRect, "Right")
	$Top = DllStructGetData($tRect, "Top")
	$Bottom = DllStructGetData($tRect, "Bottom")
	_GUIToolTip_TrackPosition($hToolTip, ($Right + $Left) / 2, $Bottom)
	_GUIToolTip_TrackActivate($hToolTip, True, 0, $hAdd)

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example