#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Opt("GUIResizeMode", 2 + 32 + 256 + 512) ; =802 - устанавливает стандартное поведение всех элементов в GUI, для которых не определёно поведение с помощью GUICtrlSetResizing.

Example()

Func Example()
	Local $iEdit, $iBtnOk, $iBtnCancel, $msg

	Opt("GUICoordMode", 2)
	GUICreate("Мой InputBox", 190, 114, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; установите стиль позволяющий изменять размер

	GUICtrlCreateLabel("Введите текст", 8, 7) ; добавляет текст информации
	GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP)

	$iEdit = GUICtrlCreateInput("Default", -1, 3, 175, 20, $ES_PASSWORD) ; добавляет поле ввода
	GUICtrlSetState($iEdit, $GUI_FOCUS)
	GUICtrlSetResizing($iEdit, $GUI_DOCKBOTTOM + $GUI_DOCKHEIGHT)

	$iBtnOk = GUICtrlCreateButton("OK", -1, 3, 75, 24) ; добавляет кнопку OK
	GUICtrlSetResizing($iBtnOk, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

	$iBtnCancel = GUICtrlCreateButton("Отмена", 25, -1) ; добавляет кнопку отмены
	GUICtrlSetResizing($iBtnCancel, $GUI_DOCKBOTTOM + $GUI_DOCKSIZE + $GUI_DOCKHCENTER)

	GUISetState() ; показывает созданное окно

	; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
	While 1
		$msg = GUIGetMsg()

		If $msg = $GUI_EVENT_CLOSE Then ExitLoop
	WEnd
EndFunc