#include <GDIP.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>

_Example()

Func _Example()
	Local $hGUI
	Local $hGraphics, $hBmp, $hBitmap
	Local $iColor, $iX, $iY, $iImageWidth, $iImageHeight
	Local $aSize

	; Инициализирует библиотеку GDI+
	_GDIPlus_Startup()

	; Создаёт GUI (нажмите ESC для выхода)
	$hGUI = GUICreate("", @DesktopWidth, @DesktopHeight)

	; Создаёт графический объект из дескриптора окна
	$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

	; Делает снимок экрана
	$hBmp = _ScreenCapture_Capture("", 0, 0, -1, -1, False)

	; Создаёт объект GDI+ Bitmap из объекта GDI Bitmap
	$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBmp)

	; Получает ширину и высоту изображения
	$aSize = _GDIPlus_ImageGetDimension($hBitmap)
	$iColor = $GDIP_DARKSEAGREEN

	$iImageWidth =  $aSize[0]
	$iImageHeight = $aSize[1]

	For $iX = 0 To $iImageWidth Step 16
		For $iY = 0 To $iImageHeight Step 16
			_GDIPlus_BitmapSetPixel($hBitmap, $iX, $iY, $iColor) ; Устанавливает цвет пикселя
		Next
	Next
	GUISetState()

	; Теперь рисует клетчатый снимок экрана
	_GDIPlus_GraphicsDrawImage($hGraphics, $hBitmap, 0, 0)

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

	; Освобождает ресурсы
	_GDIPlus_ImageDispose($hBitmap)
	_WinAPI_DeleteObject($hBmp)
	_GDIPlus_GraphicsDispose($hGraphics)

	; Закрывает библиотеку GDI+
	_GDIPlus_Shutdown()
EndFunc