#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
	Local $hGUI, $hToolbar, $aStrings[4]
	Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

	; Создаёт GUI
	$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
	$hToolbar = _GUICtrlToolbar_Create($hGUI)
	GUISetState()

	_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

	; Добавляет строки
	$aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&Новая")
	$aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Открыть")
	$aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Сохранить")
	$aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Справка")

	; Добавляет кнопки
	_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings[0])
	_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings[1])
	_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings[2])
	_GUICtrlToolbar_AddButtonSep($hToolbar)
	_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

	; Устанавливает состояние кнопки "Сохранить"
	MsgBox(4096, "Информация", 'Неопределённое состояние кнопки "Сохранить"?: ' & _GUICtrlToolbar_IsButtonIndeterminate($hToolbar, $idSave))
	_GUICtrlToolbar_SetIndeterminate($hToolbar, $idSave)
	MsgBox(4096, "Информация", 'Неопределённое состояние кнопки "Сохранить"?: ' & _GUICtrlToolbar_IsButtonIndeterminate($hToolbar, $idSave))

	; Цикл выполняется, пока окно не будет закрыто
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main