#include <GuiListBox.au3>
#include <GuiButton.au3>

Example()

Func Example()
	Local $hGUI, $hFont, $hBtn, $hListBox, $tLogFont

	$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 350, 200)

	$hBtn = _GUICtrlButton_Create($hGUI, "Кнопка со шрифтом", 10, 10, 270, 34)
	$hListBox = _GUICtrlListBox_Create($hGUI, "Жирный шрифт", 10, 50, 270, 150)

	; Заполняет ListBox пунктами
	_GUICtrlListBox_BeginUpdate($hListBox)
	_GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
	_GUICtrlListBox_EndUpdate($hListBox)

	; Характеристики шрифта на основе структуры
	$tLogFont = DllStructCreate($tagLOGFONT)
	DllStructSetData($tLogFont, "Height", 22)
	DllStructSetData($tLogFont, "Weight", 700)
	DllStructSetData($tLogFont, "Italic", True)
	DllStructSetData($tLogFont, "FaceName", 'Courier new')
	$hFont = _WinAPI_CreateFontIndirect($tLogFont)

	; Назначает шрифт элементам управления
	_WinAPI_SetFont($hBtn, $hFont)
	_WinAPI_SetFont($hListBox, $hFont)

	GUISetState()

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
	_WinAPI_DeleteObject($hFont)
EndFunc   ;==>Example