#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

; Создание GUI
GUICreate("Поиск пункта в ListView по тексту", 400, 300)
$iListView = GUICtrlCreateListView("", 2, 2, 394, 268)
$iButton = GUICtrlCreateButton('Найти пункт', 400 - 120, 300 - 25, 110, 20)
$iInput = GUICtrlCreateInput('пУнкт тЕстОвЫй', 10, 300 - 25, 200, 20)
GUISetState()

; Добавляет колонку
_GUICtrlListView_AddColumn($iListView, "Колонка 1", 200)

; Приостанавливает перерисовку
_GUICtrlListView_BeginUpdate($iListView)
; Добавляет пункты
For $i = 1 To 49
	_GUICtrlListView_AddItem($iListView, "Пункт " & $i)
Next
_GUICtrlListView_AddItem($iListView, "Пункт тестовый")
For $i = 51 To 100
	_GUICtrlListView_AddItem($iListView, "Пункт " & $i)
Next
; Восстанавливает перерисовку
_GUICtrlListView_EndUpdate($iListView)

While 1
	Switch GUIGetMsg()
		Case $iButton
			$sTmp = GUICtrlRead($iInput)
			; Получает индекс найденного пункта по тексту
			$ind = _GUICtrlListView_FindText($iListView, $sTmp, 49, False, True)
			; Прокручивает ListView к найденному пункту
			_GUICtrlListView_EnsureVisible($iListView, $ind)
		Case -3
			Exit
	EndSwitch
WEnd