#include <GuiToolbar.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает
Global $iMemo

_Main()

Func _Main()
	Local $hGUI, $hToolbar, $hNormal, $hDisabled, $hHot
	Local Enum $idBtn1 = 1000, $idBtn2, $idBtn3

	; Создаёт GUI
	$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
	$hToolbar = _GUICtrlToolbar_Create($hGUI)
	$iMemo = GUICtrlCreateEdit("", 2, 46, 396, 252, $WS_VSCROLL)
	GUICtrlSetFont($iMemo, 10, 400, 0, "Courier New")
	GUISetState()

	; Создаёт нормальный список изображений
	$hNormal = _GUIImageList_Create(32,32, 5)
	_GUIImageList_AddIcon($hNormal, 'shell32.dll', 0, True)
	_GUIImageList_AddIcon($hNormal, 'shell32.dll', 19, True)
	_GUIImageList_AddIcon($hNormal, 'shell32.dll', 5, True)
	_GUICtrlToolbar_SetImageList($hToolbar, $hNormal)

	; Создаёт список изображений для состояния недоступный
	$hDisabled = _GUIImageList_Create(32,32, 5)
	_GUIImageList_AddIcon($hDisabled, 'shell32.dll', 109, True)
	_GUIImageList_AddIcon($hDisabled, 'shell32.dll', 10, True)
	_GUIImageList_AddIcon($hDisabled, 'shell32.dll', 131, True)
	_GUICtrlToolbar_SetDisabledImageList($hToolbar, $hDisabled)

	; Создаёт список изображений для состояния при наведении на элемент
	$hHot = _GUIImageList_Create(32,32, 5)
	_GUIImageList_AddIcon($hHot, 'shell32.dll', 99, True)
	_GUIImageList_AddIcon($hHot, 'shell32.dll', 3, True)
	_GUIImageList_AddIcon($hHot, 'shell32.dll', 24, True)
	_GUICtrlToolbar_SetHotImageList($hToolbar, $hHot)

	; Добавляет кнопки
	_GUICtrlToolbar_AddButton($hToolbar, $idBtn1, 0)
	_GUICtrlToolbar_AddButton($hToolbar, $idBtn2, 1)
	_GUICtrlToolbar_AddButton($hToolbar, $idBtn3, 2)

	; Деактивирует третью кнопку
	; _GUICtrlToolbar_EnableButton($hToolbar, $idBtn1, False)
	; _GUICtrlToolbar_EnableButton($hToolbar, $idBtn2, False)
	_GUICtrlToolbar_EnableButton($hToolbar, $idBtn3, False)

	; Показывает дескрипторы списка изображений
	MemoWrite("Дескриптор списка недоступных .: 0x" & Hex(_GUICtrlToolbar_GetDisabledImageList($hToolbar)))
	MemoWrite("Дескриптор списка при наведении: 0x" & Hex(_GUICtrlToolbar_GetHotImageList($hToolbar)))
	MemoWrite("Дескриптор списка нормального .: 0x" & Hex(_GUICtrlToolbar_GetImageList($hToolbar)))

	; Цикл выполняется, пока окно не будет закрыто
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage = "")
	GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite