#include <IE.au3>

; Пример 1 - Присоединяется к браузеру, в заголовке которого "AutoIt", получает его URL
$oIE = _IEAttach("AutoIt")
MsgBox(4096, "URL", _IEPropertyGet($oIE, "locationurl"))


; Пример 2 - Присоединяется к браузеру с текстом "Быстрая рыжая лиса" на его странице
$oIE = _IEAttach("Быстрая рыжая лиса", "text")


; Пример 3 - Присоединяется к элементу браузера, встроенного в другом окне
$oIE = _IEAttach("Заголовок окна", "embedded")


; Пример 4 - Присоединяется к 3-ему элементу браузера, встроенного в другом окне
;				Используйте расширенный синтаксис заголовка окна,
;				чтобы использовать 2-е окносо строкой 'ICQ' в заголовке
$oIE = _IEAttach("[REGEXPTITLE:ICQ; INSTANCE:2]", "embedded", 3)


; Пример 5 - Создаёт массив ссылок на объекты для всех текущих экземпляров браузера
;				Первый элемент массива будет содержать количество найденных экземпляров
Local $aIE[1]
$aIE[0] = 0

$i = 1
While 1
	$oIE = _IEAttach("", "instance", $i)
	If @error = $_IEStatus_NoMatch Then ExitLoop
	ReDim $aIE[$i + 1]
	$aIE[$i] = $oIE
	$aIE[0] = $i
	$i += 1
WEnd

MsgBox(4096, "Найдено браузеров", "Количество экземпляров браузеров в массиве: " & $aIE[0])
