#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
	Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic

	; Инициализация библиотеки GDI+
	_GDIPlus_Startup ()

	; Захватывает весь экран
	$hBitmap1 = _ScreenCapture_Capture ("")
	$hImage1 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap1)

	; Захватывает область экрана
	$hBitmap2 = _ScreenCapture_Capture ("", 0, 0, 400, 300)
	$hImage2 = _GDIPlus_BitmapCreateFromHBITMAP ($hBitmap2)

	; Рисует одно изображение в другом
	$hGraphic = _GDIPlus_ImageGetGraphicsContext ($hImage1)
	_GDIPlus_GraphicsDrawImage ($hGraphic, $hImage2, 100, 100)

	; Рисует рамку вокруг вставленного изображения
	_GDIPlus_GraphicsDrawRect ($hGraphic, 100, 100, 400, 300)

	; Сохраняет изображение в файл
	_GDIPlus_ImageSaveToFile ($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

	; Очищает ресурсы
	_GDIPlus_ImageDispose ($hImage1)
	_GDIPlus_ImageDispose ($hImage2)
	_WinAPI_DeleteObject ($hBitmap1)
	_WinAPI_DeleteObject ($hBitmap2)

	; Закрывает библиотеку GDI+
	_GDIPlus_ShutDown ()

EndFunc   ;==>_Main