#include <GUIConstantsEx.au3>
#include <TabConstants.au3>

Local $tab, $iCombo, $msg, $Gui

$Gui = GUICreate("Вкладки (Tab) в GUI") ; Создаёт окно в центре экрана

GUISetBkColor(0xB4E1D3)
GUISetFont(9, 300)

$tab = GUICtrlCreateTab(10, 10, 380, 200)

GUICtrlCreateTabItem("Путь")
GUICtrlSetImage(-1, "shell32.dll", -222, 0) ; иконка вкладки
GUICtrlCreateLabel("Путь", 40, 43, 270, 17)
GUICtrlCreateButton("OK", 314, 60, 46, 25)
GUICtrlCreateInput("C:\WINDOWS\system32", 40, 60, 275, 25)

GUICtrlCreateTabItem("Выбор стиля")
GUICtrlSetState(-1, $GUI_SHOW) ; будет отображаться выбранной
GUICtrlCreateLabel("Выбери стиль", 20, 54, 250, 17)
$iCombo = GUICtrlCreateCombo("", 20, 70, 310, 120)
GUICtrlSetData(-1, "$GUI_SS_DEFAULT_TAB|$TCS_FIXEDWIDTH|$TCS_FIXEDWIDTH+$TCS_FORCEICONLEFT|$TCS_FIXEDWIDTH+$TCS_FORCELABELLEFT|$TCS_BOTTOM", "$GUI_SS_DEFAULT_TAB") ; по умолчанию стандартный стиль

GUICtrlCreateTabItem("?")
GUICtrlCreateLabel("Описание", 20, 40, 120, 17)
GUICtrlCreateButton("OK", 300, 150, 70, 30)

GUICtrlCreateTabItem("") ; определяет конец вкладок

GUICtrlCreateLabel('Можно применять иконки, стили оформления' & @CRLF & '$TCS_MULTILINE - вкладки в несколько рядов (вместо горизонтальной прокрутки)' & @CRLF & '$TCS_BUTTONS - вкладки как кнопки' & @CRLF & '$TCS_FLATBUTTONS+$TCS_BUTTONS - утопленные вкладки', 20, 230, 370, 100)

GUISetState()

; Запускается цикл опроса GUI до тех пор пока окно не будет закрыто
While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			ExitLoop
		Case $tab
			; отображает кликнутую вкладку
			WinSetTitle($Gui, "", "Вкладки (Tab) в GUI, текущая " & GUICtrlRead($tab))
		Case $iCombo
			GUICtrlSetStyle($tab, BitOR($GUI_SS_DEFAULT_TAB, Execute(GUICtrlRead($iCombo))))
	EndSwitch
WEnd