#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; Под Vist-ой Windows API "SetLocalime" может не выполняться из-за параметров безопасности

Global $iMemo

_Main()

Func _Main()
	Local $hGUI, $tCur, $tNew

	; Создаёт GUI
	$hGUI = GUICreate("Время", 400, 300)
	$iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
	GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
	GUISetState()

	; Показывает текущее локальное время
	$tCur = _Date_Time_GetLocalTime()
	MemoWrite("Текущие дата/время .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

	; Устанавливает новое локальное время
	$tNew = _Date_Time_EncodeSystemTime(8, 19, @YEAR, 3, 10, 45)
	If Not _Date_Time_SetLocalTime(DllStructGetPtr($tNew)) Then
		MsgBox(4096, "Ошибка", "Системное время не может быть установлено" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
		Exit
	EndIf
	$tNew = _Date_Time_GetLocalTime()
	MemoWrite("Новые дата/время   .: " & _Date_Time_SystemTimeToDateTimeStr($tNew))

	; Сброс локального времени
	_Date_Time_SetLocalTime(DllStructGetPtr($tCur))

	; Показывает текущее локальное время
	$tCur = _Date_Time_GetLocalTime()
	MemoWrite("Текущие дата/время .: " & _Date_Time_SystemTimeToDateTimeStr($tCur))

	; Цикл выполняется, пока окно не будет закрыто
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; Записывает строку в элемент для заметок
Func MemoWrite($sMessage)
	GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite