#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
	Local $hGUI, $hGraphics, $hBrush, $hPath, $aPoints[5][2]

	; Инициализирует библиотеку GDI+
	_GDIPlus_Startup()

	$hGUI = GUICreate("Рисует заполненный GraphicsPath", 400, 200)
	GUISetState()

	; Создаёт графический объект из дескриптора окна
	$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
	_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)

	; Создаёт объект GraphicsPath
	$hPath = _GDIPlus_PathCreate()

	; Задаёт координаты точек кривой
	$aPoints[0][0] = 4
	$aPoints[1][0] = 10
	$aPoints[1][1] = 100
	$aPoints[2][0] = 100
	$aPoints[2][1] = 190
	$aPoints[3][0] = 300
	$aPoints[3][1] = 10
	$aPoints[4][0] = 390
	$aPoints[4][1] = 100

	; Добавляет кривую в объект GraphicsPath
	_GDIPlus_PathAddCurve($hPath, $aPoints)

	; Создаёт кисть, чтобы заполнить внутреннее пространство объекта GraphicsPath
	$hBrush = _GDIPlus_BrushCreateSolid(0xFF0000FF)

	; Заполняет объект GraphicsPath
	_GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

	; Освобождает ресурсы
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_PathDispose($hPath)
	_GDIPlus_GraphicsDispose($hGraphics)

	; Закрывает библиотеку GDI+
	_GDIPlus_Shutdown()
EndFunc