#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
	Local $hGUI, $hGraphics, $hBrush, $tRectF

	; Инициализирует библиотеку GDI+
	_GDIPlus_Startup()

	$hGUI = GUICreate("_GDIPlus_LineBrushCreateFromRect", 400, 200)
	GUISetState()

	; Создаёт графический объект из дескриптора окна
	$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

	; Создаёт структуру $tagGDIPRECTF, определяющую прямоугольник для кисти линейного градиента
	$tRectF = _GDIPlus_RectFCreate(0, 0, 50, 100)

	; Создаёт кисть линейного градиента, который плавно изменяет цвет с красного на зеленый
	$hBrush = _GDIPlus_LineBrushCreateFromRect($tRectF, 0xFFFF0000, 0xFF009900, 3, 1) ; Диагональ в обратном направлении

	; Заполняет прямоугольник кистью с линейным градиентом
	_GDIPlus_GraphicsFillRect($hGraphics, 0, 0, 400, 200, $hBrush)

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

	; Освобождает ресурсы
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGraphics)

	; Закрывает библиотеку GDI+
	_GDIPlus_Shutdown()
EndFunc