#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
	Local $hGui, $btnEnlarge, $btnReduce
	$hGui = GUICreate(StringTrimRight(@ScriptName, 4), 420, 350, -1, -1)
	$hRichEdit = _GUICtrlRichEdit_Create($hGui, 'Это тест.', 10, 10, 400, 220, _
			BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
	$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
	$btnEnlarge = GUICtrlCreateButton("Увеличить шрифт", 140, 310, 120, 30)
	$btnReduce = GUICtrlCreateButton("Уменьшить шрифт", 270, 310, 120, 30)
	GUISetState()

	_GUICtrlRichEdit_SetSel($hRichEdit, 0, -1) ; Выделяет всё

	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE
				_GUICtrlRichEdit_Destroy($hRichEdit)
				GUIDelete()
				Exit
			Case $btnEnlarge
				ChangeFontSize(2)
			Case $btnReduce
				ChangeFontSize(-2)
		EndSwitch
	WEnd
EndFunc   ;==>Main

Func ChangeFontSize($d)
	Local $iOld, $iNew
	$iOld = _GUICtrlRichEdit_GetFont($hRichEdit)
	_GUICtrlRichEdit_ChangeFontSize($hRichEdit, $d)
	$iNew = _GUICtrlRichEdit_GetFont($hRichEdit)
	GUICtrlSetData($lblMsg, "Шрифт был " & $iOld[0] & " пунктов, теперь стал " & $iNew[0] & " пунктов")
EndFunc   ;==>ChangeFontSize