; Пример 1
$n = 43951789
$u = -43951789

Global $sText
; учтите, что двойное %%, выводит символ как есть, буквально '%'; здесь \n - перенос строки, \t - табуляция
$sText &= StringFormat("%%d = '%d'\n", $n) ;				'43951789'			стандартное целое
$sText &= StringFormat("%%e = '%e'\n", $n) ;				'4.395179e+007'		экспоненциальный вид  (мантисса и экспонента)
$sText &= StringFormat("%%u = '%u'\n", $n) ;				'43951789'			положительное целое число без знака
$sText &= StringFormat("%%u <0 = '%u'\n", $u) ;			'4251015507'		отрицательное число (в итоге неверный результат)
$sText &= StringFormat("%%f = '%f'\n", $n) ;				'43951789.000000'	с плавающей точкой
$sText &= StringFormat("%%.2f = '%.2f'\n", $n) ;			'43951789.00'		с плавающей точкой, 2 цифры после десятичной точки
$sText &= StringFormat("%%o = '%o'\n", $n) ;				'247523255'			восьмеричное
$sText &= StringFormat("%%s = '%s'\n", $n) ;				'43951789'			строковый, как текст
$sText &= StringFormat("%%x = '%x'\n", $n) ;				'29ea6ad'			шестнадцатеричный вид (в нижнем регистре)
$sText &= StringFormat("%%X = '%X'\n", $n) ;				'29EA6AD'			шестнадцатеричный вид (в верхнем регистре)

$sText &= StringFormat("%%+d = '%+d'\n", $n) ;			'+43951789'			знак указывающий положительное число
$sText &= StringFormat("%%+d <0= '%+d'\n\n", $u) ;			'-43951789'		знак указывающий отрицательное число

$s = 'пудель'
$t = 'много щенков'

$sText &= StringFormat("%%s = [%s]\n", $s) ;		[пудель]			стандартная строка
$sText &= StringFormat("%%10s = [%10s]\n", $s) ;		[    пудель]		выравнивание пробелами справа
$sText &= StringFormat("%%-10s = [%-10s]\n", $s) ;		[пудель    ]		выравнивание пробелами слева
$sText &= StringFormat("%%010s = [%010s]\n", $s) ;		[0000пудель]		заполнение нулями работает в строках тоже
$sText &= StringFormat("%%10.10s = [%10.10s]\n", $t) ;	[много щенк]		выравнивание слева, но с обрезкой длины превышающей 10 символов

$sText &= StringFormat("%04d-%02d-%02d\n", 2008, 4, 1) ; дата
$sText &= StringFormat("%02d:%02d:%02d\n", 8, 45, 9) ; время
$sText &= StringFormat("%04d-%02d-%02d %02d:%02d:%02d", 2008, 4, 1, 8, 45, 9) ; дата и время

MsgBox(4096, 'Сообщение', $sText)

; Пример 2
$iTime = '5'
$sText = ''

; В многоязычном интерфейсе позволяет вставить переменную в любую позицию.
$sText &= StringFormat("%s minutes passed", $iTime) & @LF
$sText &= StringFormat("прошло %s минут", $iTime)

MsgBox(0, 'Форматированная строка', $sText)

Exit

$iDec = Dec('F4E6DC')
MsgBox(0, 'Число в шестнадцатеричном виде', StringFormat("%06X", $iDec))