; Autoit Version: 3.0
; Language:       English
; Author:         Larry Bailey
; Email:          psichosis@tvn.net
; Date: November 15, 2004
;
; Script Function
; Создаёт базовый GUI программа бросания кости, обычно чтобы передвигать фишки или в нардах.
; Используется функция Random для получения случайного числа

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
#include <StaticConstants.au3>

Opt('MustDeclareVars', 1)

_Main()

Func _Main()
	Local $iBtn1, $iBtn2, $iBtn3, $iBtn4, $iBtn5
	Local $iBtn6, $iBtn7, $iBtn8, $iBtn9, $iBtn10
	Local $hGUI, $iOutput, $iDie, $msg, $results
	$hGUI = GUICreate("Игра в кости", 265, 150, -1, -1)

	GUICtrlCreateLabel("Число сторон у кубика", 25, 2, 230, 17)
	$iBtn1 = GUICtrlCreateButton("2", 5, 25, 50, 30)
	$iBtn2 = GUICtrlCreateButton("3", 65, 25, 50, 30)
	$iBtn3 = GUICtrlCreateButton("4", 125, 25, 50, 30)
	$iBtn4 = GUICtrlCreateButton("6", 5, 65, 50, 30)
	$iBtn5 = GUICtrlCreateButton("8", 65, 65, 50, 30)
	$iBtn6 = GUICtrlCreateButton("10", 125, 65, 50, 30)
	$iBtn7 = GUICtrlCreateButton("12", 5, 105, 50, 30)
	$iBtn8 = GUICtrlCreateButton("20", 65, 105, 50, 30)
	$iBtn9 = GUICtrlCreateButton("100", 125, 105, 50, 30)
	$iBtn10 = GUICtrlCreateButton("Очистить", 185, 105, 65, 30)
	$iOutput = GUICtrlCreateLabel("", 185, 45, 70, 50, BitOR($BS_PUSHLIKE, $SS_CENTER))
	$iDie = GUICtrlCreateLabel("", 185, 25, 70, 20, $SS_SUNKEN)
	GUICtrlSetFont($iOutput, 24, 800, "", "Comic Sans MS")

	GUISetState()

	; Опрос GUI пока окно не будет закрыто
	While 1
		Switch GUIGetMsg()
			Case $iBtn1
				$results = Random(1, 2, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "2 сторонний")
			Case $iBtn2
				$results = Random(1, 3, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "3 сторонний")
			Case $iBtn3
				$results = Random(1, 4, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "4 сторонний")
			Case $iBtn4
				$results = Random(1, 6, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "6 сторонний")
			Case $iBtn5
				$results = Random(1, 8, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "8 сторонний")
			Case $iBtn6
				$results = Random(1, 10, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "10 сторонний")
			Case $iBtn7
				$results = Random(1, 12, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "12 сторонний")
			Case $iBtn8
				$results = Random(1, 20, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "20 сторонний")
			Case $iBtn9
				$results = Random(1, 100, 1)
				GUICtrlSetData($iOutput, $results)
				GUICtrlSetData($iDie, "100 сторонний")
			Case $iBtn10
				GUICtrlSetData($iOutput, "")
				GUICtrlSetData($iDie, "")
			Case $GUI_EVENT_CLOSE
				ExitLoop
		EndSwitch
	WEnd
	GUIDelete($hGUI)
	Exit
EndFunc   ;==>_Main