; AutoIt Version 3.0.103
; Language:       English
; Author:         Larry Bailey
; Email:          psichosis@tvn.net
; Date: January 11, 2005
;
; Функции скрипта
; Создаёт обычный GUI, показывает
; использование label, combobox и button
; Выбор пункта в combobox и нажатие
; кнопки обновляет текст в label

#include <GuiConstantsEx.au3>

_Main()

Func _Main()
	Local $idLabel_1, $idCombo_2, $idButton1, $iMsg, $sData

	; Создаёт GUI и элементы управления
	GUICreate("Мой GUI", 191, 157, (@DesktopWidth - 191) / 2, (@DesktopHeight - 157) / 2)
	$idLabel_1 = GUICtrlCreateLabel("Label1", 30, 40, 131, 21, 0x1000)
	$idCombo_2 = GUICtrlCreateCombo("", 30, 60, 130, 21)
	GUICtrlSetData($idCombo_2, "Пункт 1|Пункт 2|Пункт 3|Пункт 4|Пункт 5")
	$idButton1 = GUICtrlCreateButton("Установить в Label", 30, 90, 130, 27)

	GUISetState()
	; Цикл выполняется, пока окно не будет закрыто
	While 1
		$iMsg = GUIGetMsg()
		Switch $iMsg
			Case $GUI_EVENT_CLOSE
				ExitLoop
			Case $idButton1 ; При нажатии кнопки изменяется текст в label
				$sData = GUICtrlRead($idCombo_2) ; Читает из выпадающего списка
				GUICtrlSetData($idLabel_1, $sData) ; Вставляет текст в label
		EndSwitch
	WEnd
	Exit
EndFunc   ;==>_Main