#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_TB = False ; Проверяет ClassName передаваемый в функции. Установите True и используйте дескриптор от другого элемента, чтобы увидеть как это работает

_Main()

Func _Main()
	Local $hGUI, $hToolbar, $fStyle
	Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp

	; Создаёт GUI
	$hGUI = GUICreate(StringTrimRight(@ScriptName, 4), 400, 300)
	$hToolbar = _GUICtrlToolbar_Create($hGUI)
	GUISetState()

	; Добавляет стандартный системный bitmaps
	Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
		Case 0
			_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
		Case 2
			_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
	EndSwitch

	; Добавляет кнопки
	_GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW)
	_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN)
	_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE)
	_GUICtrlToolbar_AddButtonSep($hToolbar)
	_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

	; Устанавливает классический стиль, чтобы увидеть изменения
	DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", $hToolbar, "wstr", 0, "wstr", 0)

	; Изменяет стиль Toolbar
	$fStyle = _GUICtrlToolbar_GetStyleFlat($hToolbar)
	MsgBox(4096, "Информация", "Включен ли стиль плоских кнопок?: " & $fStyle)
	GUISetState(@SW_LOCK)
	_GUICtrlToolbar_SetStyleFlat($hToolbar, Not $fStyle)
	GUISetState(@SW_UNLOCK)
	MsgBox(4096, "Информация", "Включен ли стиль плоских кнопок?: " & _GUICtrlToolbar_GetStyleFlat($hToolbar))

	; Цикл выполняется, пока окно не будет закрыто
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main