#include <GDIP.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hBrush, $iX, $iY

    ; Создаёт GUI
    Local $hGUI = GUICreate("Кисть двухцветного узора", 810, 610)
    GUISetState(@SW_SHOW)

    ; Инициализирует библиотеку GDI+
    _GDIPlus_Startup()
	; Создаёт графический объект из дескриптора окна
    Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

    For $i = 0 To 52
        $iX = 10 + Mod($i, 10) * 80
        $iY = 30 + Floor($i / 10) * 100
        _GDIPlus_GraphicsDrawString($hGraphic, $i, $iX, $iY - 16)

		; Создаёт HatchBrush, используемый в качестве кисти фона для заливки фигуры
        $hBrush = _GDIPlus_HatchBrushCreate($i, 0xFF00FF00, 0xFF0000FF)

		; Рисует заполненный прямоугольник
        _GDIPlus_GraphicsFillRect($hGraphic, $iX, $iY, 70, 70, $hBrush)

		; Освобождает ресурсы кисти
        _GDIPlus_BrushDispose($hBrush)
    Next


    ; Цикл выполняется, пока окно не будет закрыто
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Освобождает ресурсы
    _GDIPlus_GraphicsDispose($hGraphic)

    ; Закрывает библиотеку GDI+
    _GDIPlus_Shutdown()
EndFunc   ;==>Example
