#include <GDIP.au3>
#include <GUIConstantsEx.au3>

_Example()

Func _Example()
	Local $hGUI, $hGraphics, $hHatchBrush, $hPen
	; Координаты звезды
	Local $aPoints[11][2] = [[10], [313, 124], [225, 188], [258, 291], [170, 228], [82, 291], [115, 188], [27, 124], [136, 123], [170, 20], [204, 123]]

	; Инициализирует библиотеку GDI+
	_GDIPlus_Startup()

	$hGUI = GUICreate("Карандаш на основе кисти", 400, 350)
	GUISetState()

	; Создаёт графический объект из дескриптора окна
	$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
	_GDIPlus_GraphicsSetSmoothingMode($hGraphics, $SmoothingModeAntiAlias)

	; Создаёт HatchBrush, используемый в карандаше
	$hHatchBrush = _GDIPlus_HatchBrushCreate($HatchStyleLargeConfetti, 0xFFFFFF00, 0xFFFF00DD)

	; Создаёт карандаш на основе кисти
	$hPen = _GDIPlus_PenCreate2($hHatchBrush, 15)

	; Рисует замкнутую линию, звезду
	_GDIPlus_GraphicsDrawClosedCurve2($hGraphics, $aPoints, 0.5, $hPen)

	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE

	; Освобождает ресурсы
	_GDIPlus_PenDispose($hPen)
	_GDIPlus_BrushDispose($hHatchBrush)
	_GDIPlus_GraphicsDispose($hGraphics)

	; Закрывает библиотеку GDI+
	_GDIPlus_Shutdown()
EndFunc