#include <GDIP.au3>

_Example()

Func _Example()
	Local $hGUI, $hGraphics, $hBrush, $aXY
	Local $aColors[11] = [10, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFF0000, 0xFF0000FF, 0xFFFF0000, 0xFFFFFFFF, 0xFFFF0000, 0xFF0000FF]
	Local $aPoints[11][2] = [[10],[303, 114],[215, 178],[248, 281],[160, 218],[72, 281],[105, 178],[17, 114],[126, 113],[160, 10],[194, 113]]

	; Инициализирует библиотеку GDI+
	_GDIPlus_Startup()

	$hGUI = GUICreate("Устанавливает центр кисти градиента", 400, 300, 10)
	GUISetState()

	; Создаёт графический объект из дескриптора окна
	$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)

	; Создаёт путь кисти градиента из точек
	$hBrush = _GDIPlus_PathBrushCreate($aPoints)
	; Устанавливает цвет центра кисти градиента
	_GDIPlus_PathBrushSetCenterColor($hBrush, 0xFF00FF00)
	; Устанавливает цвета окружения кисти градиента
	_GDIPlus_PathBrushSetSurroundColorsWithCount($hBrush, $aColors)
	; Устанавливает центр кисти градиента
	_GDIPlus_PathBrushSetCenterPoint($hBrush, 175.3, 175)

	; Заполняет многоугольник используя кисть градиента
	_GDIPlus_GraphicsFillPolygon($hGraphics, $aPoints, $hBrush)

	; Получает координаты центра кисти градиента
	$aXY = _GDIPlus_PathBrushGetCenterPointI($hBrush)
	If $aXY <> -1 Then MsgBox(0, 'Сообщение', _
			'Координаты центра кисти градиента: ' & @LF & @LF & _
			@TAB & 'x=' & $aXY[0] & @LF & _
			@TAB & 'y=' & $aXY[1])

	; Освобождает ресурсы
	_GDIPlus_BrushDispose($hBrush)
	_GDIPlus_GraphicsDispose($hGraphics)

	; Закрывает библиотеку GDI+
	_GDIPlus_Shutdown()
EndFunc   ;==>_Example